Вставка типового проекта

(defun ru-block-insert-project
       (dwg_name / note_base_point dwg_props scale unit)
  ;; вставка типового проекта (setq dwg_name "c:\.ru\cad\samples\dwg\Двутавры.dwg")
  (if (findfile dwg_name)
    (progn
      (setq dwg_props
             (ru-dwgprops-obj-get-from-file dwg_name)
      ) ;_ end of setq
      (ru-dwgprops-file-show "Свойства ТПР" dwg_props)
      (if (setq note_base_point
                 (cdr (assoc 302 dwg_props))
          ) ;_ end of setq
        (setq note_base_point (ru-string-right-part note_base_point "="))
      ) ;_ end of if

      (if (setq unit
                 (cdr (assoc 301 dwg_props))
          ) ;_ end of setq
        (setq unit (ru-string-right-part unit "="))
        (if (ru-yes
              (strcat
                "Для выбранного типового проекта '"
                "'
не указано название единиц рисунка!"
                "
Принять единицу рисунка '"
                (ru-unit-name)
                "'(как в текущем)"
              ) ;_ end of strcat
            ) ;_ end of ru-msg-yes
          ;;как в рисунке
          (setq unit (ru-unit-name))
          (if (= (ru-unit-name) "м")
            (setq unit "мм")
            (setq unit "м")
          ) ;_ end of if
        ) ;_ end of if
      ) ;_ end of if

      ;; Масштаб вставки типового проекта
      (if
        (= unit "м")
         (setq scale (ru-conv-meter-to-unit 1))
         (setq scale (ru-conv-millimeter-to-unit 1))
      ) ;_ end of if
      (if note_base_point
        (princ
          (strcat "
Известное описание точки вставки ТПР: '"
                  note_base_point
                  "'
"
          ) ;_ end of strcat
        ) ;_ end of princ
      ) ;_ end of if
      (ru-block-multi-insert-scaled-rotated-or-angleask
        dwg_name
        scale
        scale
        nil
      ) ;_ end of ru-block-multi-insert-scaled-rotated-or-angleask
    ) ;_ end of progn
    (princ (strcat "
Не найден " dwg_name))
  ) ;_ end of if
) ;_ end of defun