Вывод дополнительной кнопки в статусную строку

(defun ru-acad-sbb-make-button
       (button_text button_clicked_call_back / srv)
;|
Создание кнопки и установка ее свойств
В качестве COM-сервера используется
AcadStatusBarButton.dll
Copyright 2003 ManuSoft http://www.manusoft.com

|;
  (setq *ru_sbb_maked* (vl-bb-ref '*ru_bb_sbb_maked*))
  (if (not *ru_sbb_maked*)
    (progn
      (setq srv (vlax-create-object "AcadStatusBarButton.Button"))
      (vlax-put-property srv 'Text button_text)
      (vlax-put-property srv 'Width 0)
      (vlax-put-property
        srv
        'TooltipText
        "Переключение меню ruCAD или AutoCAD"
      ) ;_ end of vlax-put-property
      (vlax-put-property srv 'TooltipEnabled :vlax-true)
      (vlax-put-property
        srv
        'LispFunctionOnClicked
        (vl-symbol-name button_clicked_call_back)
      ) ;_ end of vlax-put-property
      (vlax-put-property srv 'Visible :vlax-true)
      (setq *ru_sbb_maked* t)
      (vl-bb-set '*ru_bb_sbb_maked* *ru_sbb_maked*)
    ) ;_ end of progn
  ) ;_ end of if
  srv
) ;_ end of defun
(defun ru-acad-sbb-on-click ()
                            ;|
Функция реакции на нажатие кнопки. Автокаду посылается
команда методом SendCommand. В строке команды мы вызываем
функцию переключения меню
|;
  (vlax-invoke-method
    (vla-get-activedocument (vlax-get-acad-object))
    'SendCommand
    "(ru-menu-acad-rucad)
"
  ) ;_ end of vlax-invoke-method
  (princ)
) ;_ end of defun

(defun ru-acad-sbb-erase-button ()
                                ;|
Удаление кнопки - если понадобится
|;
  (vlax-release-object *ru_sbb_srv*)
) ;_ end of defun